[QlikSense] - Calendrier avec jour fériés dynamique

[#1]

Bonjour,

  Je souhaiterai créer un calendrier contenant la liste des jours fériés sans renseigner manuellement les jours fériés.

  Auriez-vous une fonction à intégrer dans le script de chargement permettant de calculer automatiquement les jours fériés et plus particulièrement le dimanche de Pacques.

David C.

[brunobertels]

Bonjour David

La solution présentée ici me semble la meilleur approche :

https://community.qlik.com/message/406922#406922

Bruno

[#3]

Merci Bruno, je vais regarder ça.

[brunobertels]

Bonjour

A tous hasards j'ai retrouvé çà qui pourrait t'aider

https://community.qlik.com/docs/DOC-17044

[Anonymous]

Bonjour et Merci Bruno.

Voici le script qu'on utilise, je vais demander à David de mettre son post en Résolu :

Sub JoursFeries(dateDebut, dateFin, vlisteFeries)

    Let vlisteFeries = Null();

    For vAnnee=Year(dateDebut) To Year(dateFin)

        vlisteFeries=vlisteFeries & ',' & chr(39) & makedate($(vAnnee), 1, 1) & chr(39);                 // Jour de l'an

        vlisteFeries=vlisteFeries & ',' & chr(39) & makedate($(vAnnee), 5, 1) & chr(39);                 // Fete du travail 1er Mai

        vlisteFeries=vlisteFeries & ',' & chr(39) & makedate($(vAnnee), 5, 😎 & chr(39);                 // Armistice 1945 8 Mai

        vlisteFeries=vlisteFeries & ',' & chr(39) & makedate($(vAnnee), 7, 14) & chr(39);                // Fete National 14 Juillet

        vlisteFeries=vlisteFeries & ',' & chr(39) & makedate($(vAnnee), 8, 15) & chr(39);                // Assomption 15 Aout

        vlisteFeries=vlisteFeries & ',' & chr(39) & makedate($(vAnnee), 11, 1) & chr(39);                // Toussaint 1er Novembre

        vlisteFeries=vlisteFeries & ',' & chr(39) & makedate($(vAnnee), 11, 11) & chr(39);                 // Armistice 1918 11 Novembre 

        vlisteFeries=vlisteFeries & ',' & chr(39) & makedate($(vAnnee), 12, 25) & chr(39);                // Noel

        vDatePaques = Date(Round(makedate($(vAnnee),4,day(Minute($(vAnnee)/38)/2+55))/7)*7-6);            // Dimanche de Paques

        vlisteFeries=vlisteFeries & ',' & chr(39) & vDatePaques & chr(39);                                // Dimanche de Paques

        vlisteFeries=vlisteFeries & ',' & chr(39) & Date((vDatePaques + 1), 'DD/MM/YYYY') & chr(39);    // Lundi de Paques

        vlisteFeries=vlisteFeries & ',' & chr(39) & Date((vDatePaques + 39), 'DD/MM/YYYY') & chr(39);    // Jeudi de l'Ascension

        vlisteFeries=vlisteFeries & ',' & chr(39) & Date((vDatePaques + 49), 'DD/MM/YYYY') & chr(39);    // Dimanche de Pentecote

        vlisteFeries=vlisteFeries & ',' & chr(39) & Date((vDatePaques + 50), 'DD/MM/YYYY') & chr(39);    // Lundi de Pentecote

    Next

    Let vlisteFeries = Mid(vlisteFeries,2);

    // Réinitialisation des variables

    let vDatePaques = Null();

    Let vAnnee = Null();

EndSub