Just generate something yourself using ctrl+q+q
Or look here:
Sample data
Or use this which I generated from ctrl+q+q
Transactions:
Load
'1' as TransCounter,
TransLineID,
TransID,
mod(TransID,26)+1 as Num,
Pick(Ceil(5*Rand1),'A','B','C','D','E') as Department,
Pick(Ceil(6*Rand1),'0','1','2','3','4','5') as Status,
Pick(Ceil(2*Rand1),'0','1') as OverdueFlag,
makedate(Ceil(2017-(3*Rand())),Ceil(12*Rand()),Ceil(28*Rand())) as OrderDate,
date(if(100*rand() >5,makedate('2017',Ceil(12*Rand1),Ceil(28*Rand1)),null())) as ShippedDate,
money(round(RAND()*25000,0.01)) AS Value;
Load
Rand() as Rand1,
IterNo() as TransLineID,
RecNo() as TransID
Autogenerate 10000
While Rand()<=0.5 or IterNo()=1;
MasterCalendar:
Load
TempDate AS OrderDate,
week(TempDate) As Week,
Year(TempDate) As Year,
Month(TempDate) As Month,
Day(TempDate) As Day,
'Q' & ceil(month(TempDate) / 3) AS Quarter,
Week(weekstart(TempDate)) & '-' & WeekYear(TempDate) as WeekYear,
WeekDay(TempDate) as WeekDay
;
//=== Generate a temp table of dates ===
LOAD
date(mindate + IterNo()) AS TempDate
,maxdate // Used in InYearToDate() above, but not kept
WHILE mindate + IterNo() <= maxdate;
//=== Get min/max dates from Field ===/
LOAD
min(FieldValue('OrderDate', recno()))-1 as mindate,
max(FieldValue('OrderDate', recno())) as maxdate
AUTOGENERATE FieldValueCount('OrderDate')
