I think there might be an issue with the suggested approach, because it does check that group B is a subset of A, instead it just compares the distinct count of users in both periods.
For example, if you replace your second last line with:
7, 01/02/13
the distinct count won't change and the result is the same, -20%, while user 7 has not appeared in previous period yet and should be disregarded.
I think you can potentially create a frontend only solution, but it will be probably very complex and resource extensive.
If possible, try creating a solution in the script, e.g. you can check for User appearance in the requested periods in script already.
Maybe like this (you can probably optimize this a lot):
SET DateFormat='DD/MM/YY';
T1:
LOAD * INLINE [
User_ID, Date_Logged_On
1, 01/01/13
2, 01/01/13
3, 01/01/13
4, 01/01/13
5, 01/01/13
2, 01/02/13
3, 01/02/13
1, 01/02/13
5, 01/02/13
2, 01/02/13
];
Let vStart = num(makedate(2013,1,1));
Let vEnd = num(makedate(2013,3,1));
Churn:
LOAD Date(weekstart($(vStart),iterno()-1)) as ChurnRateDate,
Date(weekstart($(vStart),iterno()-1)-30) as Date30,
Date(weekstart($(vStart),iterno()-1)-60) as Date60
AutoGenerate 1
while weekstart($(vStart),iterno()-1) <= weekstart($(vEnd));
JOIN LOAD distinct User_ID Resident T1;
Let vNumDates = NoOfRows('Churn');
for i = 0 to vNumDates-1
TMP1:
LOAD peek('ChurnRateDate',$(i),'Churn') as ChurnRateDate,
peek('User_ID',$(i),'Churn') as User_ID,
if(count(Date_Logged_On),1,0) as Flag30
Resident T1
where User_ID = peek('User_ID',$(i),'Churn')
and Date_Logged_On <= peek('ChurnRateDate',$(i),'Churn')
and Date_Logged_On > peek('Date30',$(i),'Churn');
TMP2:
LOAD peek('ChurnRateDate',$(i),'Churn') as ChurnRateDate,
peek('User_ID',$(i),'Churn') as User_ID,
if(count(Date_Logged_On),1,0) as Flag60
resident T1
where User_ID = peek('User_ID',$(i),'Churn')
and Date_Logged_On <= peek('Date30',$(i),'Churn')
and Date_Logged_On > peek('Date60',$(i),'Churn');
next i
Left Join (Churn) LOAD * Resident TMP1;
Left Join (Churn) LOAD * Resident TMP2;
drop table TMP1;
drop table TMP2;
Then, in the frontend, just create a straight table chart with dimension ChurnRateDate and as expression:
= (count({<Flag30 = {1}, Flag60={1}>} User_ID) - count({<Flag60={1}>} User_ID))
/ count({<Flag60={1}>} User_ID)
Hope this helps,
Stefan
.