topic Re: Find Match Value in QlikView

Find Match Value

DipeshVadgama — Mon, 26 Jan 2026 18:19:17 GMT

Hi All,

I am trying to find match value from "Match Name" list in "Full Name" List. If its match then I need output Match Name.

I use index and match formula in excel, but I am unable to figure it out in Qlikview.

Re: Find Match Value

sunny_talwar — Wed, 31 May 2017 15:01:52 GMT

May be this

MappingTable:

Mapping

LOAD [Match Name],

'@' & [Match Name] & '%'

FROM

[..\..\Downloads\Match.xlsx]

(ooxml, embedded labels, table is [Match Name]);

Table:

LOAD [Full Name],

TextBetween(MapSubString('MappingTable', [Full Name]), '@', '%') as [Need Output Here]

FROM

[..\..\Downloads\Match.xlsx]

(ooxml, embedded labels, table is [Full Name]);

Re: Find Match Value

DipeshVadgama — Wed, 31 May 2017 15:15:49 GMT

Thanks Sunny,

This works, If possible can you explain me how this works. Why @ & %, Can't I apply direct Mapsubstring

Re: Find Match Value

sunny_talwar — Wed, 31 May 2017 15:28:55 GMT

Without Text Between, you will just replace the specific text with a new value (or same value in your case) Test the below out.

MappingTable:

Mapping

LOAD [Match Name],

[Match Name]

FROM

[..\..\Downloads\Match.xlsx]

(ooxml, embedded labels, table is [Match Name]);

Table:

LOAD [Full Name],

MapSubString('MappingTable', [Full Name]) as [Need Output Here]

FROM

[..\..\Downloads\Match.xlsx]

(ooxml, embedded labels, table is [Full Name]);

The idea is to add a unique character in the front and end of the text you want to see and then use Text between function to pull the specific text out of the whole thing

Re: Find Match Value

DipeshVadgama — Thu, 01 Jun 2017 06:47:54 GMT

Thank Sunny,

Very helpful. I have one more question.

How to find match value from "Match Name" list in "Full Name" List. If its match then I need output Match Code value but not the match name this time.

I have attached the file for example.

Re: Find Match Value

sunny_talwar — Thu, 01 Jun 2017 11:04:03 GMT

Try this

MappingTable:

Mapping

LOAD [Match Name],

'@' & Code & '%'

FROM

[..\..\Downloads\Match (1).xlsx]

(ooxml, embedded labels, table is [Match Name]);

Table:

LOAD [Full Name],

TextBetween(MapSubString('MappingTable', [Full Name]), '@', '%') as [Need Output Here]

FROM

[..\..\Downloads\Match.xlsx]

(ooxml, embedded labels, table is [Full Name]);