topic Re: Load error with OSuser() function in QlikView

Load error with OSuser() function

Wed, 26 May 2010 18:42:41 GMT

Hi all,

I get an error for anything that goes after

load UPPER(OSuser()) as NTuser;

in my script. When I remove that line all is fine. Any ideas?

Thnx

Mat

Load error with OSuser() function

boorgura — Wed, 26 May 2010 18:45:28 GMT

Can you provide the complete script please?

Load error with OSuser() function

Wed, 26 May 2010 18:54:14 GMT

Sure:

load UPPER(OSuser()) as NTuser;

SET ThousandSep=',';
SET DecimalSep='.';
SET MoneyThousandSep=',';
SET MoneyDecimalSep='.';
SET MoneyFormat='$#,##0.00;($#,##0.00)';
SET TimeFormat='h:mm:ss TT';
SET DateFormat='M/D/YYYY';
SET TimestampFormat='M/D/YYYY h:mm:ss[.fff] TT';
SET MonthNames='Jan;Feb;Mar;Apr;May;Jun;Jul;Aug;Sep;Oct;Nov;Dec';
SET DayNames='Mon;Tue;Wed;Thu;Fri;Sat;Sun';

Let NumOfYears = $(YearsBack) + $(YearsForward) + 1;
Let NumOfMonths = $(NumOfYears)*12;
Let NumOfDays = $(NumOfYears)*365;
Let StartYear = Year(floor(now())) - $(YearsBack);
Let StartDate = Num(MakeDate($(StartYear),$(FiscalMoShift)+1));

Let LastDateKey= Date(floor(now()),'MM-DD-YYYY');

Date_src:
LOAD
$(StartDate) + iterno()-1 as DateStamp autogenerate 1 while iterno() <= $(NumOfDays) + 1;

Dates:
LOAD Distinct
DateStamp,
date(floor(DateStamp)) as DateKey,
day(DateStamp) as Day,
month(DateStamp) as Month,
year(DateStamp) as Year,
num(Month(DateStamp) + (Year(DateStamp) - $(StartYear))*12) as MonthNum,
Date(DateStamp,'MMMYY') as MonthYr,
Dual('Q' & ceil(((mid(date(DateStamp,'YYYY-MM-DD'),6,2)))/3), ceil(((mid(date(DateStamp,'YYYY-MM-DD'),6,2)))/3)) as Qtr,
if(weekday(DateStamp)>4, 0,1) as WorkDay
Resident Date_src;

Load error with OSuser() function

boorgura — Wed, 26 May 2010 19:03:56 GMT

You have no table to load from.

Use this instead:

LET NTUser = UPPER(OSuser());

That should be good for you.

Load error with OSuser() function

Wed, 26 May 2010 19:22:13 GMT

Thanks. Now, I'm trying the following script, which does not work:

LET NTUser = UPPER(OSuser());

ConfigUsers:
LOAD * INLINE [
NTuser, NTuserGroup
MYDOMAIN\PPAN, Executive
MYDOMAIN\RTHAT, Executive
];

Config:
load NTuser, NTuserGroup
resident ConfigUsers where NTuser='$(NTUser)';

drop table ConfigUsers;

Any help appreciated!

Mat

Load error with OSuser() function

boorgura — Wed, 26 May 2010 19:37:20 GMT

Please use this:

LET NTUser = UPPER(OSuser());

ConfigUsers:
LOAD * INLINE [
NTuser, NTuserGroup
MYDOMAIN\PPAN, Executive
MYDOMAIN\RTHAT, Executive
];

Config:

NoConcatenate

load NTuser, NTuserGroup
resident ConfigUsers where NTuser='$(NTUser)';

drop table ConfigUsers;

Let me know if it works or not.

Load error with OSuser() function

Wed, 26 May 2010 19:47:47 GMT

Sweet. Works nicely. Thnx!

Re: Load error with OSuser() function

Anonymous — Sat, 09 Sep 2017 08:15:30 GMT

Can we use Config: table as Mapping Load??