topic Sintax error in QlikView

Sintax error

Wed, 18 Jan 2017 10:20:44 GMT

Hi,

I'm trying to understand where i'm wrong, but I need your help.

In reference to this discussion https://community.qlik.com/thread/62449, I fixed the code according to my needs.

At first step, I wrote and tested this code, and it was ok:

Set vConcatenate = ;
Set vFileExtension = ;
Set vFoundFile = ;
Set vSubDirectory = ;
Set vPeriodo = 1;
Set vDataRif = ;


sub ScanFolder(Root)
  for each vFileExtension in 'xlsx'
    for each vFoundFile in filelist(Root & '\*.' & vFileExtension)
        FileList:
        $(vConcatenate)
            LOAD *,
            '$(vFoundFile)' as [FilenameWithPath],
            '31/12/2014' as data_rif,
            1 as id_periodo            
            FROM [$(vFoundFile)]
            (ooxml, embedded labels, table is data);
            Set vConcatenate = Concatenate;
        next vFoundFile
    next vFileExtension
   
    for each vSubDirectory in DirList(Root & '\*')   
        call ScanFolder(vSubDirectory)
    next vSubDirectory
end sub

Call ScanFolder(vDir_ProvaACLCaric);

Then, i tryied to add a nested if to the "vSubDirectory" foreach, but I really don't understand where I'm wrong:

Set vConcatenate = ;
Set vFileExtension = ;
Set vFoundFile = ;
Set vSubDirectory = ;
Set vPeriodo = 1;
Set vDataRif = ;


sub ScanFolder(Root, id_periodo)
  for each vFileExtension in 'xlsx'
    for each vFoundFile in filelist(Root & '\*.' & vFileExtension)
        FileList:
        $(vConcatenate)
            LOAD *,
            '$(vFoundFile)' as [FilenameWithPath],
            '31/12/2014' as data_rif,
            id_periodo as id_periodo            
            FROM [$(vFoundFile)]
            (ooxml, embedded labels, table is data);
            Set vConcatenate = Concatenate;
        next vFoundFile
    next vFileExtension
   
    for each vSubDirectory in DirList(Root & '\*')
        if(substringcount($(vSubDirectory)), 'dicembre_2014') > 0, $(vPeriodo) = 1,
        if(substringcount($(vSubDirectory)), 'dicembre_2015' ) > 0, $(vPeriodo) = 2,
        if(substringcount($(vSubDirectory)), 'giugno_2016' ) > 0, $(vPeriodo) = 3, 0)))       
        call ScanFolder(vSubDirectory, vPeriodo)
    next vSubDirectory
end sub

Call ScanFolder(vDir_ProvaACLCaric);

Can someone help me, please?

Re: Sintax ero

Aurelien_Martinez — Wed, 18 Jan 2017 10:26:52 GMT

Hi,

When you call your function :

Call ScanFolder(vDir_ProvaACLCaric);

the second parameter is missing

Call ScanFolder(vDir_ProvaACLCaric, 0);

Re: Sintax ero

Wed, 18 Jan 2017 10:38:03 GMT

Thank you very much, I fixed the error, but I I still have error in this section:

    for each vSubDirectory in DirList(Root & '\*')
        if(substringcount($(vSubDirectory)), 'dicembre_2014') > 0, $(vPeriodo) = 1, 
        if(substringcount($(vSubDirectory)), 'dicembre_2015' ) > 0, $(vPeriodo) = 2,
        if(substringcount($(vSubDirectory)), 'giugno_2016' ) > 0, $(vPeriodo) = 3, 0)))        
        call ScanFolder(vSubDirectory, vPeriodo)
    next vSubDirectory

Re: Sintax error

Aurelien_Martinez — Wed, 18 Jan 2017 10:44:19 GMT

IF substringcount('$(vSubDirectory)', 'dicembre_2014') > 0 THEN

SET vPeriodo = 1;

ELSEIF substringcount('$(vSubDirectory)', 'dicembre_2015') > 0 THEN

SET vPeriodo = 2;

ELSEIF substringcount('$(vSubDirectory)', 'giugno_2016' ) > 0 THEN

SET vPeriodo = 3;

ELSE

SET vPeriodo = 0;

ENDIF

Re: Sintax error

jonathandienst — Wed, 18 Jan 2017 11:01:58 GMT

For Each vSubDirectory in DirList(Root & '\*')

Let vPeriodo = If(SubStringCount(vSubDirectory, 'dicembre_2014') > 0, 1,

If(SubStringCount(vSubDirectory, 'dicembre_2015') > 0, 2,

If(SubStringCount(vSubDirectory, 'giugno_2016') > 0, 3, 0))

);

Call ScanFolder(vSubDirectory, vPeriodo);

next vSubDirectory

Re: Sintax error

Wed, 18 Jan 2017 11:43:31 GMT

Thank you very much again!