Group by

KuppuswamyS — Fri, 15 Nov 2024 23:56:27 GMT

Hello All,

I am new to QlikView. May I get help from you guys on this issue?

System hits "General Script Error" when I execute below code.

MachineUtil:
LOAD
BUDAT_POSTINGDATE as [Posting Date],
WERKS_PLANT as [%Plant],
ARBID_OBJECTID as [%Object ID],
LTXA1_CONFIRMATIONTEXT as [Confirmation Text],
ISM01_BURDENHOURS as [# Burden Hours],
ISM02_LABOURHOURS as [# Labour Hours]
FROM
$(vSourcePath)\AFRU_ORDERCONFIRMATIONS.qvd
(qvd);

LEFT JOIN
LOAD
OBJTY_OBJECTTYPE as [Object Type],
OBJID_OBJECTID as [%Object ID],
WERKS_PLANT as [%Plant],
ARBPL_WORKCENTER as [Work Center],
VERWE_WORKCENTERCATEGORY as [Work Center Category]
FROM
$(vSourcePath)\CRHD_WORKCENTERHEADER.qvd
(qvd);

LEFT JOIN
LOAD
OBJTY_OBJECTTYPE as [Object Type],
OBJID_OBJECTID as [%Object ID],
SPRAS_LANG as [Language],
KTEXT_DESC as [Description],
KTEXT_DESC_UP as [Description Up]
FROM
$(vSourcePath)\CRTX_MACHINEDESC.qvd
(qvd);

STORE MachineUtil into $(vTransformedPath)\MachineUtil.qvd (qvd);
DROP Table MachineUtil;

MachineUtilisation:
LOAD
[Posting Date],
[%Plant],
[%Object ID],
[Confirmation Text],
sum([# Burden Hours]) as [# Actual Burden Production Hours],
sum([# Labour Hours]) as [# Actual Labour Production Hours],
[Object Type],
[Work Center],
[Work Center Category],
[Language],
[Description],
[Description Up]
FROM
$(vTransformedPath)\MachineUtil.qvd (qvd)
where [Confirmation Text] > ''
Group By
[%Object ID];
STORE MachineUtilisation into $(vTransformedPath)\MachineUtilisation.qvd (qvd);
DROP Table MachineUtilisation;

Re: Group by

Kushal_Chawda — Tue, 22 Sep 2020 09:30:04 GMT

@KuppuswamyS You need to include all the fields in group by

MachineUtilisation:
LOAD
[Posting Date],
[%Plant],
[%Object ID],
[Confirmation Text],
sum([# Burden Hours]) as [# Actual Burden Production Hours],
sum([# Labour Hours]) as [# Actual Labour Production Hours],
[Object Type],
[Work Center],
[Work Center Category],
[Language],
[Description],
[Description Up]
FROM
$(vTransformedPath)\MachineUtil.qvd (qvd)
where [Confirmation Text] > ''
Group By
[Posting Date],
[%Plant],
[%Object ID],
[Confirmation Text],
[Object Type],
[Work Center],
[Work Center Category],
[Language],
[Description],
[Description Up];

topic Re: Group by in QlikView

Group by

Re: Group by