topic Re: Difference between peek() and previous() funcation in QlikView

Difference between peek() and previous() function

Wed, 04 Aug 2010 05:16:53 GMT

What is difference between peek() and previous() function.

Regards

Ashish Srivastava

Difference between peek() and previous() funcation

Wed, 04 Aug 2010 06:18:51 GMT

Hi Ashish,

I think the difference between Peek and Previous is that Previous always returns the data present in the previous row of the table but Peek can return data from any row based on the row mentioned in the function.

eg. previous(value) returns the data for 'value' from the previous row

peek(Value,-3) returns the 3rd last record loaded into the table.

previous(value) and peek(value) will return the same record from the previous row

Cheers,

Haneesh

Difference between peek() and previous() funcation

johnw — Thu, 05 Aug 2010 01:41:16 GMT

Previous looks at your INPUT table. Peek looks at your OUTPUT table.

Difference between peek() and previous() funcation

Thu, 05 Aug 2010 08:29:58 GMT

Dear John

Thanks for reply .

But I don't understand what is INPUT table and OUTPUT table.

Regards

Ashish Srivastava

Difference between peek() and previous() funcation

johnw — Thu, 05 Aug 2010 16:46:38 GMT

Output is the table you're creating. Input is the table you're reading from.

OutputTable:
LOAD field
RESIDENT InputTable;

Difference between peek() and previous() funcation

Fri, 06 Aug 2010 08:37:27 GMT

Thank John now i understood.

Regards

Ashish Srivastava

Difference between peek() and previous() funcation

Thu, 26 May 2011 08:58:10 GMT

Hi John. If you do a concantenate Load and you use a Peek function in the Load statement, how would this affect the working of Peek? I've just spent a lot of troubleshooting time on some Peeks that would not behave because of the Concatenate qualifier and I'm wondering why. Thanks for your always valuable input! (apologies for this being all on one line. for some reason I can't press 'enter' in this edit box )

Difference between peek() and previous() funcation

johnw — Fri, 27 May 2011 00:18:57 GMT

I'm actually not certain how it would work with a concatenate load. I would think that the peek() should be able to refer to ANY row in the table you're building, even those that existed before you started concatenating the last source of data. But it certainly wouldn't surprise me if I'm wrong. It would almost surprise me more if I'm right. What are you seeing happening?

Re: Difference between peek() and previous() funcation

IAMDV — Fri, 27 May 2011 15:11:38 GMT

John - Thank you for the explanation.

Ashish - The post you had marked answered is not really the answer. It is confusing for other users who want to read this thread. I think it should be John's post which should be the answer.

Many thanks - DV

Re: Difference between peek() and previous() funcation

johnw — Fri, 27 May 2011 17:08:58 GMT

I decided to test out peek() with concatenate. You can indeed refer to rows that were in the table before you started concatenating. This script:

Data:
LOAD * INLINE [
ID, Value
1, 1
2, 2
3, 3
];
CONCATENATE (Data)
LOAD 4 as ID, peek('Value') as Value
AUTOGENERATE 1
;
CONCATENATE (Data)
LOAD ID+4 as ID, peek('Value',-4) as Value
RESIDENT Data
;

Produced the results I thought it should produce:

ID Value
1 1
2 2
3 3
4 3
5 1
6 2
7 3
8 3

Re: Difference between peek() and previous() funcation

Fri, 10 Jan 2014 06:55:36 GMT

Hi John,

Thanks for your brief explanation,

1.Can i use Peek function inside into previous function.

2.Can i use previous function inside into Peek function.

Regards,

Raja.

Re: Difference between peek() and previous() funcation

nihhalmca — Sun, 05 Mar 2017 08:59:35 GMT

Hi John,

We can use previous() in OUTPUT table like:

OUTPUT:

Load

Sales,

Previous(Sales) as Previous_Sales

From table;

Re: Difference between peek() and previous() funcation

nihhalmca — Sun, 05 Mar 2017 09:01:30 GMT

Hi Ashish,

Please mark it Jhon post as correct answer.

Re: Difference between peek() and previous() funcation

johnw — Mon, 06 Mar 2017 17:05:06 GMT

You can use previous() while creating an output table. But previous() looks at the previous row of the input table, not the previous row in the output table. For instance, you could not use previous(Previous_Sales), because Previous_Sales doesn't exist in the input table. But you could use peek(Previous_Sales), because peek() looks at the output table.

Re: Difference between peek() and previous() funcation

nihhalmca — Thu, 16 Mar 2017 15:48:52 GMT

Thanks for explanation John.

However we can use Peek() at INPUT table right, for instance

Table1:

Load

Date

From QVD;

vLastDate = Peek('Date',Table1); //getting record from loaded table)

Here Table1 is INPUT table right?

Thanks,

Nihhal.

Re: Difference between peek() and previous() funcation

johnw — Thu, 16 Mar 2017 21:13:33 GMT

I probably wouldn't call it input or output since it isn't in a load statement. But you write a script like the below, and then I would completely agree that peek(X,recno()-2,'Input') is reading the input table, a counterexample to my overly-simplistic pronouncements, and it further seems to be the equivalent of previous(X).

Input:
LOAD * INLINE [
X
1
3
5
2
4
];
Output:
LOAD
X as InputX
,X+1 as X
,recno() as recno
,rowno() as rowno
,previous(X) as PrevX
,peek(X) as PeekX
,peek(X,recno()-2,'Input') as PeekInputX2
,peek(X,rowno()-2,'Output') as PeekOutputX2
RESIDENT Input
WHERE X > 2
;
DROP TABLE Input;

From the output, and I think this makes sense in terms of what the functions are doing, so I think it's always true, though I'm not fully confident:

previous(X) = peek(X,recno()-2,'Input')
peek(X) = peek(X,rowno()-2,'Output')

So yes, when we explicitly tell peek() which table to use, it can reference any table we want - input, output, or other. As the help text states it, "If no table_name is stated, the current table is assumed." What I'm trying to drive home about this is that in a load statement, the "current table" is the table you are creating (output), not the data source you are reading data from (input). Previous() would always refer to the data source you are reading from (input), not the table you are creating (output). I think this is where most people are likely to get confused, likely to make mistakes, so it's the point I was pushing. But yes, as you point out, using the third parameter, you can make peek() look at any table, including the input table.

Peek() on the input table might even be a practical alternative to previous() in some cases. Probably easier to do peek(X,recno()-5,'Input') than previous(previous(previous(previous(X)))). It just seems a little confusing to have -2 go one step back, -5 go four steps back, but that's what happens when functions are defined inconsistently.

peek(): "0 denotes the first record, 1 the second, and so on."
recno(): "The first record is number 1."

Time for my angry face. Bad Qlik! No cookie!