Bom tardei
mas acho que agora foi....
Basicamente e o mesmo script com algumas melhoras no final
Minha logica:
O problema esta que ele pelo flag de dias trabalhados esta fazendo o que deveria o que eu precisa fazer a descobrir qual e o registro que esta errado ( porque tem o dia trabalho, depois vem a folga, logo se eu descobrir qual e o registro da folga, eu consigo acha o registro que a data deve ser alterar , que seria no caso o antecessor ao registro da folga), sempre que for o mesmo grupo, mesmo porte e a data final do registro a cima for maior que atual (porque noa faz sentindo, porque eu ordei por data) significa que esse registro a cima precisa ser alterado.
Obs Importante: Meu calendario daqui e de Segunda a Sexta (estou fora do brasil, por isso e calendario diferente no brasil e domingo a sexta), entao no if troca para 7 e 1
/************************************************************************/
// 1 - Faco a leitura da Base Nao modelada
/************************************************************************/
Base_Modelada:
LOAD * INLINE [
Nome , Dia , Dias Produtividade , Grupo , Porte
Maria , 29/08/2016 , 1 , Grupo 1 , M
Maria , 30/08/2016 , 1 , Grupo 1 , M
Maria , 31/01/2017 , 1 , Grupo 1 , M
Maria , 31/01/2017 , 1 , Grupo 2 , M
Maria , 02/02/2017 , 1 , Grupo 3 , P
Maria , 03/03/2017 , 1 , Grupo 3 , P
Maria , 04/03/2017 , 0 , Grupo 3 , P
Maria , 05/03/2017 , 1 , Grupo 3 , P
Maria , 05/03/2017 , 1 , Grupo 3 , G
Maria , 06/03/2017 , 1 , Grupo 3 , G
João , 07/03/2017 , 1 , Grupo 3 , G
João , 08/03/2017 , 0 , Grupo 4 , G
João , 09/03/2017 , 1 , Grupo 3 , G
João , 09/03/2017 , 1 , Grupo 3 , M
];
/************************************************************************/
// 2 - Descobrir qual e o menor Data por grupo por pessoa
//
/************************************************************************/
Min_Data_Por_status:
LOAD
Min(Dia) as MinDtSituacaoPerDay,
Grupo,
Nome,
Porte,
[Dias Produtividade]
Resident Base_Modelada
Group By
Grupo,
Nome,
Porte,
[Dias Produtividade]
;
/************************************************************************/
// 3 - Descobrir qual e o maior horario por Equipamento
// e e por Status
/************************************************************************/
Max_Data_Por_status:
LOAD
Max(Dia) as MaxDtSituacaoPerDay,
Grupo,
Nome,
Porte,
[Dias Produtividade]
Resident Base_Modelada
Group By
Grupo,
Nome,
Porte,
[Dias Produtividade]
;
/************************************************************************/
// 4 - Crio uma tabela somente com Status e ATM para fazer
// a modelagem final
/************************************************************************/
BaseModeladaFinal:
NoConcatenate
LOAD Distinct
Nome,
Grupo,
Porte
Resident Base_Modelada
;
DROP Table Base_Modelada;
/************************************************************************/
// 5 - Faco o Join para tabela somente na tabela com status
// assim trago o menor para a tabela final
/************************************************************************/
Left Join (BaseModeladaFinal)
LOAD
Grupo,
Nome,
Porte,
MinDtSituacaoPerDay as DtInicialStatus,
[Dias Produtividade]
Resident Min_Data_Por_status;
DROP Table Min_Data_Por_status;
/************************************************************************/
// 6 - Faco o Join para tabela somente na tabela com status
// assim trago o maior para a tabela final
/************************************************************************/
Left Join(BaseModeladaFinal)
LOAD
Grupo,
Nome,
Porte,
MaxDtSituacaoPerDay as DtFinalStatus,
[Dias Produtividade]
Resident Max_Data_Por_status
;
DROP Table Max_Data_Por_status;
/**************************************************************/
//Descobrindo o registro que esta com problema e arruma
/**************************************************************/
Ajustado:
NoConcatenate
LOAD Distinct
RowNo() as Seq,
*,
if(Previous(Grupo) = Grupo and
Previous(Porte) = Porte and
Previous(DtFinalStatus) > DtFinalStatus , 1 ,0) as [Flag Divergencia Data],
if(Previous(Grupo) = Grupo and
Previous(Porte) = Porte and
Previous(DtFinalStatus) > DtFinalStatus , Num(DtFinalStatus)-1, Null()) as [Data Final Corrigida],
if( [Dias Produtividade] = 0 , 'Folga','Trabalhado') as Status
Resident BaseModeladaFinal
order by DtInicialStatus , Nome, Grupo , Porte;
DROP Table BaseModeladaFinal;
/**********************************************************************/
//Mapping Cara corrigidr a data
/**********************************************************************/
//Obs: o If aqui e para garantir que sempre vai jogar para sexta feira, tire se achar necessario.
MappingCorrecao:
mapping
LOAD
Previous(Seq) as SeqCorrigido,
if(Num(WeekDay([Data Final Corrigida])) = 7 , [Data Final Corrigida] -1,
if(Num(WeekDay([Data Final Corrigida])) = 1 ,[Data Final Corrigida]-2, [Data Final Corrigida] )
) as [Data Final Corrigida]
Resident Ajustado
Where [Flag Divergencia Data] = 1
;
DROP Field [Flag Divergencia Data], [Data Final Corrigida] from Ajustado;
/***********************************************/
//Base Final
/***********************************************/
BaseConsolidada:
NoConcatenate
LOAD
Grupo,
Nome,
Porte,
DtInicialStatus,
[Dias Produtividade],
Status,
ApplyMap('MappingCorrecao',Seq,DtFinalStatus) as DtFinalStatus
Resident Ajustado
;
DROP Table Ajustado;
fica assim:
| Nome | Dias Produtividade | Grupo | Porte | DtInicialStatus | DtFinalStatus | Status |
|---|
| Maria | 1 | Grupo 1 | M | 29/08/2016 | 31/01/2017 | Trabalhado |
| Maria | 1 | Grupo 2 | M | 31/01/2017 | 31/01/2017 | Trabalhado |
| Maria | 1 | Grupo 3 | P | 02/02/2017 | 03/03/2017 | Trabalhado |
| Maria | 0 | Grupo 3 | P | 04/03/2017 | 04/03/2017 | Folga |
| Maria | 1 | Grupo 3 | G | 05/03/2017 | 06/03/2017 | Trabalhado |
