Or using some script like : -
SimpleLatLong:
LOAD * INLINE [
CONTID,CONTINENT,Latitude,Longitude
1,Europe,54.525961,15.255119
2,North America,54.525961,-105.255119
3,South America,-8.783195,-55.491477
4,Asia,34.047863,100.619655
5,Africa,-8.783195,34.508523
6,Oceania,-27,133
7,Micronesia,6.887351,158.215072
];
//*********************************************
//Random Table Generator
//*********************************************
SET vRandChar = Chr(Floor(Rand() * 94) + 33); //Character
SET vRandCharU = Upper(Chr(Floor(Rand() * 26) + 65)); //Uppercase Character
SET vRandCharL = Lower(Chr(Floor(Rand() * 26) + 97)); //Lower Character
SET vRandTime = MakeTime(Floor(Rand() * ($2-$1)) + $1, Floor(Rand() *60),Floor(Rand()*60)); //Time Between $1 Hour to $2 Hour (24 Hour Notation)
MapSector:
MAPPING LOAD * INLINE [
SECTORID,SECTOR
1,Investment Banking
2,Cards
3,Retail Banking
4,Commercial Banking
];
MapContinent:
MAPPING LOAD * INLINE [
CONTID,CONTINENT
1,Europe
2,North America
3,South America
4,Asia
5,Africa
6,Oceania
7,Micronesia
];
LongMap:
MAPPING LOAD CONTID,
Longitude
RESIDENT SimpleLatLong;
LatMap:
MAPPING LOAD CONTID,
Latitude
RESIDENT SimpleLatLong;
DROP TABLE SimpleLatLong;
EmployeeDistribution:
LOAD *,
ApplyMap('MapContinent',CONTID) AS CONTINENT,
ApplyMap('LongMap',CONTID) AS Longitude,
ApplyMap('LatMap',CONTID) AS Latitude,
EMPLOYEECOUNTYEAR & CONTID AS %INFLATIONKEY,
interval(TIMESPENT,'hhhh:mm:ss')*24*5 AS AVERGAGETIMESPENT,
ROUND(COUNTOFEMPLOYEE / 100 * CEIL(RAND() * 3)) AS UNCOMPLIANT;
LOAD CEIL(RAND() * 7) AS CONTID,
ApplyMap('MapSector',CEIL(RAND() * 4)) AS SECTOR,
$(vRandCharU) & 1 AS TeamNames,
CEIL(RAND() * 400)*50 AS AVERAGESALARYGBP,
CEIL(RAND() * 4) + 2009 AS EMPLOYEECOUNTYEAR,
CEIL(RAND() * 756)*10 AS COUNTOFEMPLOYEE,
IF(CEIL(RAND() * 2)=1,'Male','Female') AS GENDER,
$(vRandTime(8,17)) AS TIMESPENT
AutoGenerate (30);
LEFT JOIN (EmployeeDistribution)
LOAD DISTINCT %INFLATIONKEY,
.03 AS INFLATIONRATE
RESIDENT EmployeeDistribution;
SET vRandChar = NULL(); //Character
SET vRandCharU = NULL(); //Uppercase Character
SET vRandCharL = NULL(); //Lower Character
