Compter Variable

[#1]

Bonjour,

Je contacte la communauté pour une question toute bête mais à laquelle je n'arrive pas à trouver de réponse.

Voilà, j'ai créer une variable à partir d'une fonction if, et obtient un résultat satisfaisant.

Ce que je souhaite maintenant faire est compter combien de fois 1 apparaît, 2 apparaît et ainsi de suite. Avec un champs, il suffit de faire Count(Champs=1). Je pensais faire pareil avec ma variable, mais impossible.

Quelqu'un aurait-il une idée ? J'imagine que ma syntaxe est mauvaise ou que ce n'est tout simplement pas possible avec une variable.

Merci d'avance,

Cordialement,

Audran.

[sfatoux72]

Bonjour,

Je ne comprend pas ton problème. Une variable contient une seul valeur alors qu'un champs en contient 1 par ligne de données.

Peux-tu joindre une ou plusieurs copie d'écran pour illustrer ton propos afin que l'on puisse bien comprendre ce que tu as fait et quel est exactement ton problème

[#3]

Bonjour Sébastien,

Tout d'abord, merci beaucoup pour votre réactivité habituelle.

Mon problème est le suivant, j'ai grâce à votre aide réussi à créer un code couleur.  En utilisant cette ligne dans l'expression:

if(Sum(if(Date(Date#([Date bes.],'DD.MM.YYYY'),'DD.MM.YYYY')<today()+7,[Qté requise])) > Sum([Utilis. libre])+sum([Quantité d'ordre]),

     Black(),

     if(Sum(if(Date(Date#([Date bes.],'DD.MM.YYYY'),'DD.MM.YYYY')<today()+14,[Qté requise])) > Sum([Utilis. libre])+sum([Quantité d'ordre]),

          Red(),

          Green()

     )

)

Par la suite, afin de trier mes données, j'ai associé un ordre de priorité:

if(Sum(if(Date(Date#([Date bes.],'DD.MM.YYYY'),'DD.MM.YYYY')<today()+7,[Qté requise])) > Sum([Utilis. libre])+Sum([Quantité d'ordre]),

     1,

     if(Sum(if(Date(Date#([Date bes.],'DD.MM.YYYY'),'DD.MM.YYYY')<today()+14,[Qté requise])) > Sum([Utilis. libre])+Sum([Quantité d'ordre]),

          2,

          3

     )

)

Ce que j'aimerais maintenant faire est compter le nombre de lignes pour chaque couleurs. En créant une mesure principale, j'arrive à intégrer cette formule, mais je ne peux malheureusement pas la réutiliser dans l'éditeur d'expression. D'où mon idée de créer une variable avec cette formule et de compter le nombre de 1, 2 et 3, mais pour l'instant pas de résultats.

Merci d'avance de votre aide,

Audran.

[sfatoux72 · Accepted solution]

Bonjour,

Voici une proposition :

Ajouter un champ dans votre script de chargement (vous pourrez bien sur nommé le champs et les valeurs comme vous le souhaiterez en adaptant le code en conséquence):

Load *

Inline [

CatégorieCouleur

    1

    2

    3

];

Ajouter une table sur votre feuille:

Dimension

• CatégorieCouleur

Expression

Pick(

    Match(CatégorieCouleur, 1, 2, 3),

    Sum(Aggr(if(Sum(if(Date(Date#([Date bes.],'DD.MM.YYYY'),'DD.MM.YYYY')<today()+7,[Qté requise])) > Sum([Utilis. libre])+Sum([Quantité d'ordre]), 1, 0), Article, CatégorieCouleur)),

      Sum(Aggr(if(Sum(if(Date(Date#([Date bes.],'DD.MM.YYYY'),'DD.MM.YYYY')<today()+7,[Qté requise])) > Sum([Utilis. libre])+Sum([Quantité d'ordre]), 0, if(Sum(if(Date(Date#([Date bes.],'DD.MM.YYYY'),'DD.MM.YYYY')<today()+14,[Qté requise])) > Sum([Utilis. libre])+Sum([Quantité d'ordre]), 1, 0)), Article, CatégorieCouleur)),

      Sum(Aggr(if(Sum(if(Date(Date#([Date bes.],'DD.MM.YYYY'),'DD.MM.YYYY')<today()+7,[Qté requise])) > Sum([Utilis. libre])+Sum([Quantité d'ordre]), 0, if(Sum(if(Date(Date#([Date bes.],'DD.MM.YYYY'),'DD.MM.YYYY')<today()+14,[Qté requise])) > Sum([Utilis. libre])+Sum([Quantité d'ordre]), 0, 1)), Article, CatégorieCouleur))

)

[#5]

Parfait, ça marche. Merci beaucoup pour votre aide !!! 🙂