Qlik Sense - Como somar apenas contratos de estados diferentes?

[dsaguiar95]

Olá pessoal,

Tenho tabelas parecidas com essas:

Credores:
LOAD * INLINE [
CNPJ Credor , Cidade Credor , UF Credor
1 ,A ,BA
1 ,A ,BA
2 ,B ,SP
3 ,C ,MG
4 ,D ,CE
];

Contratos:
LOAD * INLINE [
CNPJ Credor , UF Contrato, Quantidade Contratos
1 ,BA ,2
1 ,SP ,2
2 ,SP ,2
3 ,MG ,2
4 ,CE ,2
];

Preciso somar as quantidades de contratos, mas, somente os contratos que ocorreram em estados diferentes do estado do credor. Tentei resolver com Set Analysis, mas, não deu muito certo...

Usei essa expressão:

Sum({<[CNPJ Credor]={"=[UF Credor]<>[UF Detran]"}>}[Quantidade Contratos])

Porém, eu acabo somando todos os contratos de credores que realizaram vendas fora do seu estado de origem.

Como eu posso resolver isso?

OBS.: Sou novo no Qlik...

[Thiago_Justen_ · Accepted solution]

Boa noite @dsaguiar95 ,

Permita-me sugerir algo no script. Sugiro criar uma FlagContrato para facilitar teu desenvolvimento em tela.

Rode o script abaixo no teu ambiente e veja o resultado.

Credores:
LOAD * INLINE [
"CNPJ Credor" , "Cidade Credor" , "UF Credor"
1 ,A ,BA
1 ,A ,BA
2 ,B ,SP
3 ,C ,MG
4 ,D ,CE
];


Map_Credores:
Mapping Load
	"CNPJ Credor",
	"UF Credor"
Resident Credores;

Contratos:
LOAD
	*,
    If(ApplyMap('Map_Credores',"CNPJ Credor")<>"UF Contrato",
    	1*"Quantidade Contratos",
        0
    )															As FlagContrato
;
LOAD * INLINE [
"CNPJ Credor" , "UF Contrato", "Quantidade Contratos"
1 ,BA ,2
1 ,SP ,2
2 ,SP ,2
3 ,MG ,2
4 ,CE ,2
];

Em tela basta realizar Sum(FlagContrato) e ser feliz.

Abs e Sucesso!!

[dsaguiar95]

Olá, Desculpa pela demora em responder, mas, utilizei assim e deu certo. Obrigado!