Table Not Found Join

[Yaakov_kris]

Hi, 

I am trying to join 3 tables in Qlik Sense, however, whenever I do this, I get an error that the table is not found. Please, find the script below (Treatment_Details is not found). What am I doing wrong?

Treatment_Details:

Load
    Car_Number as License_Plate_Number,
    Order_id as OrderID,
    Date_Start,
    Date__Finish as Date_Finish,
    MakeDate(Right(Date_Start,4),Mid(Date_Start,3,2),Left(Date_Start,2)) AS Date_Start_Date,
    MakeDate(Right(Date__Finish,4),Mid(Date__Finish,2,2),Left(Date__Finish,2)) AS Date_Finish_Date
FROM [$(Folder)/Dwh_Order_Vehicle_Replacement.qvd](QVD);

Left Join(Treatment_Details)
Load
	OrderID,
    License_Plate_Number,
    BranchID,
    SupplierID,
    Order_TypeID
FROM [$(Folder)/Dwh_Overlapping_Dim_Repair_Order.qvd](QVD);


Left Join(Treatment_Details)
Load
	CompanyID,
    License_Plate_Number,
    OrderID,
    ActivityID,
    Activity,
    Activity_Group
FROM [$(Folder)/Dwh_Overlapping_Dim_Repair_Treatment.qvd](QVD);

Store Treatment_Details Into  [$(Folder)/Treatment_Details.qvd](Qvd);// פיזית

Drop Table Treatment_Details;

[Taoufiq_Zarra]

@Yaakov_kris 

I think the problem is the Treatment_Details table is not created.

if you run only this script in the tab I think it will work.

check before if you have a table with the same columns that generates a concatenation

[Yaakov_kris]

Hi Taoufiq,

Thanks a lot for your reply, it seems indeed to be an issue, however, I am not sure how to solve it. Do I need to create the table Treatment_Details  separately? Or what should I do, so that it will be created? I am switching from SQL, and not sure how join should be implemented...

I would really appreciate your help!

[Vegar]

Could it be that you already have a table containing similar fields as  Treatment_Details?

If so, then try to use NoConcatenate  load statement like this:

Treatment_Details:

NoConcatenate Load
Car_Number as License_Plate_Number,
etc...

[rwunderlich]

The Load for Dwh_Order_Vehicle_Replacement.qvd did not create a "Treatment_Details" table. Rather, the loaded rows were concatenated the the existing "Order_Vehicle_Replacement" table that was created earlier (I think on the first tab).  This is Qlik's "auto concatenate" feature which occurs when the fields in a load match the fields in an already loaded table. If you don't want this table to concatenate, add the NoConcatenate prefix to thee Treatment_Details load. 

How do I know this is what happened?  In your script output messages is the line:

Order_Vehicle_Replacement << Dwh_Order_Vehicle_Replacement

which means input table "Dwh_Order_Vehicle_Replacement" (your qvd) was output to "Order_Vehicle_Replacement".

-Rob
http://www.easyqlik.com
http://masterssummit.com
http://qlikviewcookbook.com