Query on Section Access script

[hopkinsc]

Hi all,Can anyone tell me if there is a problem when trying to do a resident load in section access please?

I am trying to do the following but it's not working.

Security:
LOAD * INLINE [
ACCESS, USERID, PASSWORD
Admin, Admin, Admin
User, User, User
];

Concatenate (Security)
LOAD
NTNAME,
ACCESS,
PROJECTCODE
FROM
C:\Subsea7\QVDev\PMSR\ChrisSecurity.xlsx
(ooxml, embedded labels, table is Sheet1);

Section Access;
Load *

Resident Security;

Section Application;

Drop Table Security;

Many thanks

Chris.

[Miguel_Angel_Baeyens]

Hi,

Section Application means anywhere but in the Section Access itself. Section Application is where the "normal" script is. Note that in QlikView it does not matter necessarily where to load a table, because all links will be created at the end of the load script between tables that share a field name.

So your script should look like

Security:
LOAD ...
CONCATENATE ...
Section Access;
LOAD *
RESIDENT Security;
Section Application;
// Tables here of normal load script

Hope that helps.

Miguel

[hopkinsc]

Hi Miguel,

So are you saying that the followinbg should work?

TMPSecurity:
LOAD * INLINE [
ACCESS, USERID, PASSWORD, NTNAME
Admin, Admin, Admin,*
User, User, User,*
];

Concatenate (TMPSecurity)
LOAD
NTNAME,
ACCESS,
PROJECTCODE
FROM
C:\Subsea7\QVDev\PMSR\ChrisSecurity.xlsx
(ooxml, embedded labels, table is Sheet1);

Section Access;
LOAD *
Resident TMPSecurity;

Section Application;

When i reload this and attempt to reopen the QVW it states i that my access is denied..

I have set up my NTNAME as admin and i should have access to 1 project code out of 3.

[Miguel_Angel_Baeyens]

Hi,

I think you need to change this:

Concatenate (TMPSecurity)
LOAD 
'*' AS USERID, // This line is new
'*' AS PASSWORD, // this line is new
NTNAME,
ACCESS,
PROJECTCODE
FROM
C:\Subsea7\QVDev\PMSR\ChrisSecurity.xlsx
(ooxml, embedded labels, table is Sheet1);

Add the field PROJECTCODE with "*" in the INLINE table as well.

Hope that helps.

Miguel

[hopkinsc]

Sorry to be a pain, i cannot get it to work, it keeps locking me out.

This is my new script..

TMPSecurity:
LOAD * INLINE [
ACCESS, USERID, PASSWORD, NTNAME, PROJECTCODE
Admin, Admin, Admin,*,*
User, User, User,*,*
];

Concatenate (TMPSecurity)
LOAD
'*' as USERID,
'*' AS PASSWORD,
NTNAME,
ACCESS,
PROJECTCODE
FROM
C:\Subsea7\QVDev\PMSR\ChrisSecurity.xlsx
(ooxml, embedded labels, table is Sheet1);

Section Access;
LOAD *
Resident TMPSecurity;

Section Application;

[Miguel_Angel_Baeyens · Accepted solution]

Chris,

Are fields and values uppercase?

TMPSecurity:
LOAD * INLINE [
ACCESS, USERID, PASSWORD, NTNAME, PROJECTCODE
ADMIN, ADMIN, ADMIN,*,*
USER, USER, USER,*,*
];

Concatenate (TMPSecurity)
LOAD 
'*' AS USERID,
'*' AS PASSWORD,
Upper(NTNAME) AS NTNAME,
Upper(ACCESS) AS ACCESS,
Upper(PROJECTCODE) AS PROJECTCODE
FROM
C:\Subsea7\QVDev\PMSR\ChrisSecurity.xlsx
(ooxml, embedded labels, table is Sheet1);

If that does not work, please post the excel and QVW file (remove all sensitive data and charts but keep the section access script) so we can check further. You can either comment the Section Access line just to check whether the table is or is not concatenating as expected.

Hope that helps.

Miguel

[hopkinsc]

Hi Miguel,

My NTNAME was lowercase!! I have just changed it and it now seems to be working. Thanks for your help, Sorry to be a pain!

Many thnaks

Chris.

[Miguel_Angel_Baeyens]

Hi Chris,

Nevermind, that usually happens. I'm glad to help but please mark helpful and correct answers as such, so the next user can find it out easily.

Thanks!

Miguel