Limitando filtro em tabela

[DimesDias]

Olá comunidade Qlik Sense.

Minha dúvida é a seguinte...

Tendo a tabela de exemplo acima, gostaria de permitir a seleção dos dados, preservando todas as linhas das tickets que contém itens localizados, como mostra abaixo.

Nesse exemplo, há uma seleção do Encaminhamento para 'Em análise', sem ocultar as demais linhas da mesma ticket encontrada. Assim, as tickets que não possuírem nenhuma entrada de 'Em análise' em Encaminhamento, não devem aparecer na lista. Sou iniciante em Qlik Sense, já pesquisei bastante, mas ainda não encontrei algo que me permita fazer isso. Além do mais, também gostaria de destacar a linha com o dado pesquisado numa cor diferente. Desde já, agradeço o apoio. Abraços.

Na tabela acima, desejo permitir filtros

[mario_sergio_ti]

Olá meu amigo, a quanto tempo, recebi seu link... Vamos lá...

Faz o seguinte via script, poderá fazer algo baseado nesta ideia:

Fiz um modelo para facilitar o entendimento...

[Tab_Ticket]:
Load
	RecNo()									As 'ID', //Evitar o distinct do load abaixo
	Ceil(RecNo()/2)							As 'Ticket',
	Pick(Match(Odd(RecNo()),-1,0),1,2)		As 'Ordem',
	Pick(Ceil(3*Rand()),'A','B','C') 		As 'Assunto',
	Pick(Ceil(3*Rand()),'Protocolado','Despachado','Em análise')
    										As 'Encaminhamento'
AutoGenerate 10;

Left Join ([Tab_Ticket])
Load Distinct
	Ticket,
	'Ticket Em Análise'						As 'Status Ticket'
Resident [Tab_Ticket]
	Where Match(Encaminhamento, 'Em análise')
;

Resultado:

Obs.: Ao utilizar Distinct em uma das tabela que irá ser afetado por um Contatenate ou Join, o resultado do Distinct será para todo o conjunto. Neste caso, inclua a chave na tabela desejada para evitar este efeito.

Agora poderá utilizar o campo Status Ticket para filtrar o conjunto...

[DimesDias · Accepted solution]

Obrigado meu amigo

[mario_sergio_ti]

Se deseja ter a opção de filtra com e sem análise:

[Tab_Ticket]:
Load
	RecNo()									As 'ID', //Para evitar o distinct do load abaixo
	Ceil(RecNo()/2)							As 'Ticket',
	Pick(Match(Odd(RecNo()),-1,0),1,2)		As 'Ordem',
	Pick(Ceil(3*Rand()),'A','B','C') 		As 'Assunto',
	Pick(Ceil(3*Rand()),'Protocolado','Despachado','Em análise')
    										As 'Encaminhamento'
AutoGenerate 10;

Left Join ([Tab_Ticket])
Load 
	Ticket,
	If(	WildMatch(Concat(distinct Encaminhamento,', '),'*Em análise*'),
		'Ticket Em Análise',
		'Ticket Sem Análise') 				As 'Status Ticket'
Resident [Tab_Ticket]
	Group By Ticket
;

Resultado: