You don't need the nulls to be explicit in your dimension, you could combine the two terms with an and, and you'd be well served by making a SALES_SALES_MONTH field:
if(SALES_SALES_DATE>=PeriodStart and SALES_SALES_DATE<=PeriodEnd,SALES_SALES_MONTH)
Also, calculated dimensions tend to slow down charts, so if you can actually select the date range based on the period start and end, or simply have some other way of selecting the date range, you could then just use SALES_SALES_MONTH for best performance.
Your expression for $C_Market could also be significantly simplified and the performance improved. First, define a variable with a single parameter ($1) for the common part of the expression:
LET vWhatever = 'SALES_PRICE + (Constant - SALES_MILEAGE)*$1
+ (AgeAssumption - SALES_SALE_AGE)*marketagecoef
+ (marketmsrpass - SALES_MSRP)*MSRPcoef'
Then convert your nested ifs to a combination of set analysis and pick. I think this:
avg({<SALES_PRICE_SCORE={">=$(=MinScore) <=$(=MaxScore)"}
,SALES_SALE_AGE={">=$(=MinAge) <=$(=MaxAge)"}
,SALES_MILEAGE_CLASS={'1','2','3','4','5'}>}
pick(num(SALES_MILEAGE_CLASS)
,$(vWhatever(MC1))
,$(vWhatever(MC2))
,$(vWhatever(MC3))
,$(vWhatever(MC4))
,$(vWhatever(MC5))))
OK, now let's look at what we need to do to calculate that for January 2010. Well, assuming we've added our SALES_SALES_MONTH field, I think we just need to add that to the set analysis:
avg({<SALES_PRICE_SCORE={">=$(=MinScore) <=$(=MaxScore)"}
,SALES_SALE_AGE={">=$(=MinAge) <=$(=MaxAge)"}
,SALES_MILEAGE_CLASS={'1','2','3','4','5'}
,SALES_SALES_MONTH={'Jan 2010'}>}
pick(num(SALES_MILEAGE_CLASS)
,$(vWhatever(MC1))
,$(vWhatever(MC2))
,$(vWhatever(MC3))
,$(vWhatever(MC4))
,$(vWhatever(MC5))))
I'm also wondering if we can put the pick inside of the variable.
avg({<SALES_PRICE_SCORE={">=$(=MinScore) <=$(=MaxScore)"}
,SALES_SALE_AGE={">=$(=MinAge) <=$(=MaxAge)"}
,SALES_MILEAGE_CLASS={'1','2','3','4','5'}
,SALES_SALES_MONTH={'Jan 2010'}>}
$(vWhatever(pick(num(SALES_MILEAGE_CLASS),MC1,MC2,MC3,MC4,MC5))))
I almost certainly have syntax or other errors, unfortunately. It's hard to get everything right on the first pass with an expression this big while rushing and unable to test. But hopefully you'll get the idea.
Also, I suspect you could do even better by making an explicit connection between the SALES_MILEAGE_CLASS and the MCx to use in your data model, perhaps by converting the MCx fields to a single field by changing columns to rows in some table. Very hard to say for sure without knowing your data and data model, though.
