Qlik Sense fetching all tables in postgre SQL

[prasennav]

Hello Qlikers,

****************************************************** SRCIPT **************************************************

LIB CONNECT TO 'PostgreSQL_Database';

SQLTableList:

LOAD "TABLE_NAME" as TableNames;
select table_name as "TABLE_NAME"
from information_schema.tables where table_schema = 'public';

Let vTableCount = NoOfRows('SQLTableList');

Let vTableCountQVD = '[' & NoOfRows('SQLTableList') & ']';

For i = 0 To $(vTableCount) -1

LET vMyTableName = '"public".'&'"'&Peek('TableNames', $(i), 'SQLTableList') &'"'&;
LET vMyTableNameQVD = Replace(Peek('TableNames', $(i), 'SQLTableList'), ' ', '');

$(vMyTableNameQVD):
SQL SELECT * FROM $(vMyTableName);

STORE $(vMyTableNameQVD) INTO [lib://QVD_PATH/$(vMyTableNameQVD).qvd] (qvd);

DROP Table $(vMyTableNameQVD);

Next i

***************************************************** END ****************************************

Regards,

Prasenna

[Levi_Turner · Accepted solution]

Hey there, this code looks to run fine on my end:

LIB CONNECT TO 'PostgreSQL';
SQLTableList:
LOAD 
	"TABLE_NAME" as TableNames;
SELECT 
	table_name as "TABLE_NAME"
FROM information_schema.tables where table_schema = 'public';

Let vTableCount = NoOfRows('SQLTableList');
Let vTableCountQVD = '[' & NoOfRows('SQLTableList') & ']';

Trace $(vTableCount);
Trace $(vTableCountQVD);

FOR i = 0 To $(vTableCount)-1
	LET vMyTableName = '"public".'&'"'&Peek('TableNames', $(i), 'SQLTableList') &'"'&;
	LET vMyTableNameQVD = Replace(Peek('TableNames', $(i), 'SQLTableList'), ' ', '');

	$(vMyTableNameQVD):
    LOAD *;
	SQL SELECT 
    	*
	FROM $(vMyTableName);

	STORE $(vMyTableNameQVD) INTO [lib://data/$(vMyTableNameQVD).qvd] (qvd);
	DROP Table $(vMyTableNameQVD);
NEXT i

[sergioabr_tocca]

Thank you!!

Worked here too!